#!/usr/bin/env tclsh
 set usage {
    usage: vgrep textfile &
    Show the given textfile. If strings are entered
    into the top entry widget, filter only those lines
    that match (case-indepent, spaces mean .*)
 }
 if {[llength $argv] != 1} {puts stderr $usage; exit 1}
 package require Tk

 proc main argv {
    set font {Arial 12}
    pack [entry .e -font $font] -fill x
    bind .e <KeyRelease> {rewrite .e .t}
    pack [scrollbar .y -command ".t yview"] -side right -fill y
    pack [text .t -wrap none -yscroll ".y set" -font $font] \
        -fill both -side left -expand 1
    .t tag configure blue -foreground blue
    set ::data [readlines [lindex $argv 0]]
    rewrite .e .t
    focus -force .e
 }
 proc rewrite {entry text} {
    global data
    $text delete 1.0 end
    set re [string map {" " .*} [$entry get]]
    foreach line $data {
        if {$re eq "" || [regexp -nocase $re $line]} {
            foreach {file path} [split $line ";"] break
            $text insert end $file black " ; $path\n" blue
        }
    }
    wm title . "[int [$text index end-2c]] hits - vgrep $::argv"
 }
 proc int x {expr {int($x)}}
 proc readlines filename {
    set f [open $filename]
    split [read -nonewline $f][close $f] \n
 }
 main $argv
 bind all <Escape> {exec tclsh $argv0 $argv &; exit}