if 0 {[Richard Suchenwirth] 2004-12-25 - I don't know why, but this Xmas
somehow unusual clocks interest me most. Here's a very simple one with 24
hour display (the black/white disk) plus minutes (the red arc running
round the disk).

[http://mini.net/files/arcclock.gif]

Black and white obviously stand for day and night; by
the angle of the black/white divide you can tell the hour (noon is
horizontal with white up, midnight is horizontal with black up) measured
at top of the disk. The minute display allows reading at roughly 5
minutes precision. The screenshot was taken at 11:49.

The GUI is just a [canvas] with three items:
}
 package require Tk

 pack [canvas .c -width 60 -height 60]
 .c create arc 5 5 55 55 -fill red -outline red \
    -start 90 -tag min
 .c create oval 10 10 50 50 -fill white -outline white
 .c create arc 10 10 50 50 -fill black -extent 180 -tag night
#-- I need this [every] now and then :)
 proc every {ms body} {eval $body; after $ms [info level 0]}

 proc update'arc'clock w {
    scan [clock format [clock sec] -format %H] %d hour
    scan [clock format [clock sec] -format %M] %d minute
    $w itemconfig night -start [expr ($hour+$minute/60.)*-15]
    $w itemconfig min -extent [expr $minute*-6]
 }
 every 1000 {update'arc'clock .c}
 
 bind . <Escape> {exec wish $argv0 &; exit}

----
if 0 {
[rmax] - Here is a slight variation of update'arc'clock that uses
the red arc to represent both, minutes and seconds:}

 proc update'arc'clock w {
    set sec [clock sec]
    scan [clock format $sec -format %H] %d hour
    scan [clock format $sec -format %M] %d minute
    scan [clock format $sec -format %S] %d second
    $w itemconfig night -start [expr ($hour+$minute/60.)*-15]
    $w itemconfig min -start [expr $minute*-6+90]
    $w itemconfig min -extent [expr (60-$minute+$second)*-6]
 }

----
Too bad no one got you a Time By Design [http://www.timebydesign.com/] watch for Christmas ;)  This is somewhat like their pie watch. - [RS] can't see that page, as it requires a Flash player - but I'm less interested in consumer goods than in the freedom of being my own clockmaker :^) A happy new year to all!

----
[[ [Category Date and Time] | [Arts and crafts of Tcl-Tk programming] ]]
}