Richard Suchenwirth 2007-08-17 - Looking at Tcl modules, I wanted to know how to produce such a sourceable module file which contains both Tcl scripts and one DLL (and thus does more than the Tcl module creation script). Here is my take:
#!/usr/bin/env tclsh
set usage {
usage: make_tm outfilename ?tclfile...? ?dllfile initfunc?
Creates a Tcl module file 'outfilename' from the specified tclfiles
and/or maximally one DLL.
}
if {[llength $argv] == 0} {puts stderr $usage; exit 1}
proc main argv {
set outf [open [lindex $argv 0] w]
foreach a [lrange $argv 1 end] {
switch -- [file extension $a] {
.tcl {
puts $outf "\#-- from $a"
set f [open $a]
fcopy $f $outf
close $f
}
.dll {
set f [open $a]
fconfigure $f -translation binary
puts $outf "\#-- from $a"
puts $outf "set tmp \[open /tmp/[file tail $a] w\]"
puts $outf {
set f [open [info script]]
fconfigure $f -translation binary
set data [read $f][close $f]
set ctrlz [string first \u001A $data]
fconfigure $tmp -translation binary
puts -nonewline $tmp [string range $data [incr ctrlz] end]
close $tmp
}
puts $outf "load /tmp/[file tail $a] [lindex $argv end]"
puts -nonewline $outf \u001A
fconfigure $outf -translation binary
fcopy $f $outf
close $f
break
}
default {error "cannot handle file $a"}
}
}
close $outf
}
main $argv