ulis: The gotos are gone but we still need to gracefully break out of an erroneous sequence. So we have the 'break'.

The pitfall with 'break' is that we can only break out of the current block.

Here is a mechanism for breaking out of named blocks.

The gotos are gone (except for [GOTO in Tcl]) but the labels come back.

On a structured manner, indeed.

----

Usage:

defining a named block
  
  : label block
  
breaking out of this named block
    
  break label

----

  # the break command
  
  proc break {{label ""}} \
  {
    if {$label != ""} \
    {
      # set break flag
      set ::break::break 1
      # set stopping label
      set ::break::$label 1
    }
    # do break
    return -code break
  }

  # the label (:) command
  
  proc : {label args} \
  {
    # create namespace, create our label
    namespace eval ::break set $label 0
    # execute
    set rc [catch { uplevel 1 $args } rs]
    # get state of our label and clean-up
    set flag [set ::break::$label]
    unset ::break::$label
    # break mechanism
    if {[info exists ::break::break]} \
    {
      if {$flag} \
      { # stop breaking here
        unset ::break::break
      } \
      elseif {$rc == 0} \
      { # continue breaking 
        return -code break
      }
    }
    # return return event
    global errorInfo errorCode
    return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rs
  }

----

The test

  catch { console show }
  set level0 "break label test"
  : label1 \
  while 1 \
  {
    puts "inside level 1"
    : label2 \
    while 2 \
    {
      puts "inside level 2"
      puts $level0
      puts "* breaking level 1"
      break label1
      error "should not happen 2"
    }
    error "should not happen 1"
  }
  puts "back to level 0"

----

The result

  inside level 1
  inside level 2
  break label test
  * breaking level 1
  back to level 0

----

With that you can still use 'break' or 'return -code break'.

You can also break out of any named block.

A fine extension would be to break out of a named script.