http://www.purl.org/tcl/home/man/tcl8.4/TclCmd/while.htm

----
while - Execute script repeatedly as long as a condition is met 

    :   '''while''' ''test body''

The '''while''' command evaluates ''test'' as an expression (in the same way that [expr] evaluates its argument). The value of the expression must a proper boolean value; if it is a true value then ''body'' is executed by passing it to the Tcl interpreter. Once ''body'' has been executed then ''test'' is evaluated again, and the process repeats until eventually ''test'' evaluates to a false boolean value.  [Continue] commands may be executed inside ''body'' to terminate the current iteration of the loop, and [break] commands may be executed inside ''body'' to cause immediate termination of the '''while''' command.  The '''while''' command always returns an empty string. 

Note: ''test'' should almost always be enclosed in braces.  If not, variable substitutions will be made before the '''while''' command starts executing, which means that variable changes made by the loop body will not be considered in the expression. This is likely to result in an infinite loop.  If ''test'' is enclosed in braces, variable substitutions are delayed until the expression is evaluated (before each loop iteration), so changes in the variables will be visible. For an example, try the following script with and without the braces around `$x<10`: 
======
 set x 0
 while {$x<10} {
    puts "x is $x"
    incr x
 }
======
Where you want to create a loop that continues forever, the standard idiom is:
======
while 1 { ... }
======
(Where `1` may be substituted with any other true value.) In this case, it is expected that the loop body will contain something that causes the loop to exit by some other means (e.g., [break], [return], [exit], ...)

<<discussion>>
The only case where the test need not be braced is the endless loop (which should contain a [break] command inside):
 while 1 {...}

Or a [return]--there could be returns instead of break.  Also, [CL]
can imagine writing
      while $test_variable {...}
as a collapsed test-forever combination.

----
While discussing at the Tcl'ers Chat a while that would be safe in safe interpreters [GPS] came up with these:

 $ tclsh8.4
 % rename while real.while
 % proc do.while {cond body} { if {$cond} {uplevel 2 $body} }
 % proc while {cond body} { set start [clock seconds]; real.while 1 { do.while $cond $body; if {[clock seconds] >= ($start + 600)} { return -code error "too much time used"}}}

GPS And yes I know that $cond should be uplevel'd... 

GPS Note that 600 seconds is somewhat crazy.  I think 30 or 20 is good.

GPS Another trick would be to prevent calls to while while within a while.

GPS There could be a global lock (protected from set) that would just return -code error "existing while running" if the lock is active.

dkf Why the do.while in there?

GPS just seemed easier to type out do.while and think of this as units rather than one big proc 

GPS Here's another without the do.while:

 % rename while real.while
 % proc while {cond body} { set start [clock seconds]; real.while 1 { if {[uplevel [linsert $cond 0 expr]]} { uplevel $body } else return; if {[clock seconds] > ($start + 10)} { return -code error "time limit exceeded in while loop"}}}

[US] See also [DoS]

<<discussion>>
**See also**
   * [for]
   * [if]
   * [expr]
   * [foreach]

<<categories>> Arts and crafts of Tcl-Tk programming |Tcl syntax help | Command | Control Structure