#!/bin/sh
 # next line restarts with tclsh \
        exec tclsh $0 ${1+"$@"}
 #
 # Author: Mark Oakden https://wiki.tcl-lang.org/MNO
 # Version: 1.0
 #
 # calculate Easter Sunday using the algorithm given at 
 # http://www.faqs.org/faqs/astronomy/faq/part3
 #
 # assumes Gregorian calendar
 #
 proc easterdate { year } {
     #
     # G is "golden number"
     #
     set G [expr {($year % 19) + 1}]
     #
     # H is intermediate in calculating C
     #
     set H [expr {int($year / 100)}]
     #
     # C is "century term"
     #
     set C [expr {(-1 * $H) + int($H/4) + int(8*($H+11)/25)}]
     #
     # first we need the paschal full moon.
     # the following is in days before april 19 with a couple of exceptions
     #
     set rawdays [expr {((11*$G)+$C) % 30}]
     #
     # exceptions if rawdays = 0 use days=1
     # if rawdays = 1 and G >= 12 use days=2
     # else use days=rawdays
     #
     if { $rawdays == 0 } then {
        set days 1
     } elseif { $rawdays == 1 && $G >= 12} {
        set days 2
     } else {
        set days $rawdays
     }
     #
     # now find the day that this falls on:-
     #
     set apr19 [clock scan "04/19/$year 12:00"]
     # %w is week day number Sun=0 
     set pfmweekdaynum [clock format [add_days $apr19 -$days] -format "%w"]
     #
     # Easter sunday is the next Sunday _strictly_ after PFM, so
     # if pfmweekday is sunday, we want 7 days after pfm
     # if pfmweekday is monday, we want 6 days after pfm etc.
     # i.e. we want to take (7-pfmweekdaynum) days after pfm
     #
     set easterdate [add_days $apr19 [expr {-($days - 7 + $pfmweekdaynum)}]]
 
     return $easterdate
 }
 
 proc add_days {time days} {
     if {[info tclversion] < "8.5"} {
         set res [clock scan "$days days" -base $time]
     } else {
         set res [clock add $time $days days]
     }
     return $res
 }

 for { set i 1995 } { $i <= 2015 } { incr i } {
     puts "Easter Sunday in $i will be on [clock format [easterdate $i] -format {%b %d}]"
 }

proc gregorianEasterSunday { year } {

  # returns date (ISO format yyyy-mm-dd) of Easter Sunday for the given year 
  # http://www.ptb.de/cms/fachabteilungen/abt4/fb-44/ag-441/darstellung-der-gesetzlichen-zeit/wann-ist-ostern.html

    set x $year    ;# use variable names as in "wann-ist-ostern.html"

  # k: century
    set k [ expr { $x/100 } ]                           

  # auxiliary computations
    set m [ expr { 15 + (3*$k + 3)/4 - (8*$k + 13)/25 } ]     
    set s [ expr { 2 - (3*$k + 3)/4 } ]                     
    set a [ expr { $x % 19 } ]
    set d [ expr { (19*$a + $m) % 30 } ]
    set r [ expr { $d/29 + ($d/28 - $d/29) * $a/11 } ]

  # og: date of full moon in March
    set og [ expr { 21 + $d - $r } ]

  # sz: first sunday in march
    set sz [ expr { 7 - ($x + $x/4 + $s) % 7 } ]

  # oe: intermediate
  # os: Easter Sunday (number of days counted from March 1st -> 32 = April 1st)
  # om: month (March or April) of Easter
    set oe [ expr { 7 - ($og-$sz) % 7 } ]
    set os [ expr { $og + $oe } ]
  # 'wann-ist-ostern.html' ends here - rest is my own responsibility
    set om [ expr { 3 + $os/32 } ]

  # day in month
    if { $os > 31 } {
        set os [ expr { $os - 31 } ]
    }

    return "$x-[format %02d $om]-[format %02d $os]"

}