Running starkits without Tclkit

Sarnold 2006/02/09 : If you want doctools processing without Tclkit, there are solutions.

With ActiveTcl 8.4.12 already installed :

Download dtp.kit
Save a launcher.tcl file, which content is at the bottom of this page
Run a tclsh with the following command :

tclsh launcher.tcl dtp.kit doc html pkgfoo.man > pkgfoo.html

With this script, you may even run zip or tar file if they are structured like this :

+ ROOT
|
+- main.tcl
|
+-+- lib
| |
| +- <various extensions>
...

The script has been tested with ActiveTcl 8.4.12, but should work on every modern ActiveTcl distro.

'''Launcher (launcher.tcl)'''

package require vfs
set __load [lindex $argv 0]
set ext [file extension $__load]
switch -exact -- $ext {
    .tar {
        package require vfs::tar
        set cmd vfs::tar::Mount
    }
    .zip {
        package require vfs::zip
        set cmd vfs::zip::Mount
    }
    .kit {
        package require vfs::mk4
        set cmd vfs::mk4::Mount
    }
    default {error "unknown extension : $ext"}
}

$cmd $__load $__load.0
set argv0 [lindex $argv 0]
set argv [lrange $argv 1 end]
lappend auto_path $__load.0/lib
source $__load.0/main.tcl

Category Tclkit