namespace eval RawKeys {}
set ::RawKeys::Flag 0
set ::RawKeys::LastEvent {-1 0 -1}
set ::RawKeys::Delay 50

proc ::RawKeys::Init {userPressHandler userReleaseHandler} {
    bind . <KeyPress> [list ::RawKeys::pressHandler %k $userPressHandler]
    bind . <KeyRelease> [list ::RawKeys::releaseHandler %k $userReleaseHandler]
} 

proc ::RawKeys::pressHandler {keycode userHandler} {
    variable LastEvent
    variable Delay
    variable Flag
    set Flag 1
    set deliver 1
    if {[lindex $LastEvent 0] == $keycode && \
        ([clock clicks -milliseconds] - [lindex $LastEvent 2]) < $Delay} {
        set deliver 0
    }
    set LastEvent [list $keycode 1 [clock clicks -milliseconds]]
    if {$deliver} {
        $userHandler $keycode
    }
}   

proc ::RawKeys::releaseHandler {keycode userHandler} {
    variable LastEvent
    variable Delay
    variable Flag
    set deliver 1
    set Flag 0
    set LastEvent [list $keycode 0 [clock clicks -milliseconds]]
    update
    if {$Flag} {
        set deliver 0
    }
    if {$deliver} {
        $userHandler $keycode
    }
}    

#################################### Example ################################### 

catch {console show}
puts "Enter the blank window and press/release random keys" 

array set ::pressed {}

proc press keycode {
    set ::pressed($keycode) {}
    puts "=== pressed $keycode! === ([lsort [array names ::pressed]])"
} 

proc release keycode {
    catch {unset ::pressed($keycode)}
    puts "=== release $keycode! === ([lsort [array names ::pressed]])"
}

::RawKeys::Init press release