Version 12 of A little file searcher

Richard Suchenwirth 2002-07-21 - I needed such a little tool at work, and thought that other Tclers could use it too. Basically it is a small UI wrapper for searching a text file (like a no-frills grep). Specify your search term in the entry above, hit <Return>, and see in the text which lines from the file given at startup matched. For convenience, case is ignored (one might make this switchable); the entry is cleared on cursor <Up>; and the number of matching lines is displayed in the end.

Currently I don't need it, but with a few lines more, encoding configuration (e.g. for Chinese or Korean) could be built in... Only, typing the search term would require a little input manager (as in taiku goes multilingual).

 proc ui {} {
    entry     .e -bg white -textvar search
    bind .e <Return> {search $search .t}
    bind .e <Up>     {set search ""}
    text      .t -yscrollcommand ".y set" -bg white -wrap word
    scrollbar .y -command ".t yview"

    grid .e - -sticky ew
    grid .t .y -sticky news
    grid columnconfig . 0 -weight 1
    grid rowconfig    . 1 -weight 1
 }
 proc readfile {file varName} {
    upvar \#0 $varName data
    set fp [open $file]
    set data [split [read $fp] \n]
    close $fp
   #wm title . $file
    wm title . "File: $file"
 }
 proc search {re w} {
    global data
    $w delete 1.0 end
    set n 0
    foreach line $data {
        if {[regexp -nocase -- $re $line]} {
            $w insert end $line\n
            incr n
        }
    }
    $w insert end "Found $n lines"
    $w see end
 }
 #readfile "FileSearcher.tcl" data
  readfile [lindex $argv 0] data
  ui

HJG Calling this script without a filename as argument puts up an error-message. It would be nice to catch this...

Arts and crafts of Tcl-Tk programming | Category Application