Version 15 of Tiny Excel-like app in plain Tcl/Tk

dbohdan 2015-03-25: The following code is a Tk spreadsheet inspired, title included, by http://jsfiddle.net/ondras/hYfN3/ . Halfway through writing it I found the tiny spreadsheet and lifted the idea of tracing variable reads to trigger recalculation from it. One important difference from the tiny spreadsheet is that TEAIPTT does not require a Tcl expr patch.

Feature comparison with the JavaScript version

* Lines are assumed to be up to 100 characters long (because the under-30-line JavaScript spreadsheet uses lines longer than 80 characters, 100 is the next common limit and using lines of unlimited length would feel like cheating).

The smallest JS spreadsheet is currently this one: http://xem.github.io/sheet/ (227 bytes for the minimal version, 267b if we add automatic persistence).

Screenshot

Code

#!/usr/bin/wish
foreach row {0 1 2 3 4 5 6} {
    grid {*}[lmap {column} {"" A B C D E F} {
        set cell $column$row
        set widget [if {$column eq "" || $row == 0} {
            ::ttk::label .label$cell -text [expr { $row ? $row : $column}]
        } else {
            set ::formula($cell) [set ::$cell ""]
            trace add variable ::$cell read recalc
            ::ttk::entry .cell$cell -textvar ::$cell -width 10 -validate focus \
                    -validatecommand [list ::reveal-formula $cell %V %s]
        }]
    }]
}
proc recalc {cell args} {
    catch {set ::$cell [uplevel #0 [list \
           expr [regsub -all {([A-F][1-6])} $::formula($cell) {$\1}]]]}
}
proc reveal-formula {cell event value} {
    if {$event eq "focusin"} {
        if {$::formula($cell) ne ""} { set ::$cell =$::formula($cell) }
        .cell$cell selection range 0 end
        .cell$cell icursor end
    } else { ;# focusout
        if {![regexp {^=(.*)} $value -> ::formula($cell)]} { set ::formula($cell) "" }
        foreach otherCell [array names ::formula] { recalc $otherCell }
    }
    return 1
}

Discussion

AMG: Exchanged the row and column foreach lines so that the tab key moves across rather than down.

dbohdan 2015-03-28: xem, it is neat just how much functionality your spreadsheet packs in 0x00-0xE2 but it looks like it only recalculates formulas one step at a time. I.e., if you have A1 set to =B1 and B1 set to =C1 and then put the number 5 into C1 it will take two onblur events before the value propagates back to A1. This also means you can create stable infinite loops that will cycle values and NaNs between cells.

I wonder how much you could golf the Tcl/Tk version if you try to optimize for character count rather than line count and relax the requirement on recalc. Any takers? A page like Golfed spreadsheet would be appropriate for that. I also wonder what would be the minimal overhead of adding full recalculation with circular reference prevention to xem's JS version.

aspect 2015-03-29: Fixed deletion of formulas and reduced by using lmap, taking advantage of -textvariable to eliminate the set-cell proc and eliminating the test in recalc because expr will error on an empty expression. Without set-cell, some explicit selection management is required on focusin, reducing the saving. This might be improved with some careful event binding, rather than -validate.