##+###################################################
 # NAME snitfinddialog
 # SYNOPSIS 
 #    snitfindialog path ?args?
 # DESCRIPTION
 #   snitfilendialog provides a standard find dialog layout 
 #   all buttons and the entries are accessable via the subcommand
 #   the components are: find, next (standard tk buttons), entry (standard tk entry)
 # STANDARD OPTIONS
 #   delegated is -textvariable to the entry component
 #   all other options if required must be send via a subcommand
 # WIDGET OPTIONS
 #   -findcmd The command to invoke if "Find" is pressed.
 #   -findnextcmd The command to invoke if "Find Next" is pressed.
 #   -case Case sensitivity of search either true or false. Defaults to false.
 #   -word Matches whole words only true or false. Defaults to false.
 #   -forward Forward (true) or backward (false) searches. Defaults to true.
 # WIDGET COMMAND
 #   pathName componentname ?args?
 #      without args it returns the component path to be saved inside a variable
 #      with args it evaluates args in the context of the component 
 #      if the first argument of args is bind a binding for the component is created 
 # AUTHOR
 #    Dr. Detlef Groth [email protected]
 # HISTORY
 #    20/11/2003 Version 0.1 initial release
 #    25/11/2003 Version 0.1.1 changed puts to wm title .
 #    27/11/2003 Version 0.2 update to snit 0.91 removing the component subcommand instead 
 #                           using expose
 #    31/12/2005 Version 0.2.1 - added "tkwait" and "grab" to force dialog over other windows + added button to launch

 package require snit 0.91
 
 snit::widget snitfinddialog {
    hulltype toplevel
    expose entry
    expose find
    expose next
    delegate option -findcmd to find as -command
    delegate option -findnextcmd to next as -command
    delegate option -textvariable to entry
    option -case 0
    option -word 0
    option -forward yes
    constructor {args} {
        wm resizable $win false false
        pack [frame $win.left] -side left -padx 5 -pady 5 -ipadx 5 -ipady 5 \
                  -expand yes -fill both
        pack [frame $win.right] -side left -padx 5 -pady 5 -ipadx 5 -ipady 5 \
                  -expand yes -fill both
        install find using button $win.right.search -text " Find " -width 15  
        pack $find -side top -padx 5 -pady 8
        
        install next using button $win.right.searchnext -text " Find Next " -width 15
        pack $next -side top -padx 5 -pady 12
        
        install entry using entry $win.left.entry
        pack $entry -side top -padx 5 -pady 5 -expand yes -fill x
        
        pack [frame $win.left.bottom] -side top
        pack [frame $win.left.bottom.left] -side left
        pack [checkbutton $win.left.bottom.left.words -text "Whole Words ?  " \
              -variable [varname options(-word)]] -side top -padx 5 -pady 5 -anchor w
        
        pack [checkbutton $win.left.bottom.left.uclc -text  "Case sensitive ?" \
              -variable [varname options(-case)]]  -side top -padx 5 -pady 5 -anchor w
       
        pack [labelframe $win.left.bottom.right -text " Direction "] -side left \
                  -expand yes -fill both
        pack [radiobutton $win.left.bottom.right.forward -text "Forward " \
              -variable [varname options(-forward)] -value yes] -side top -anchor w -padx 5
        pack [radiobutton $win.left.bottom.right.backward -text "Backward" \
              -variable [varname options(-forward)] -value no] -side top -anchor w  -padx 5
       
        $self configurelist $args
    }
  
 }
 # EXAMPLE of usage
 proc Test_Find {} {
    global textvar
    # testing mFind
    proc Next {} {
        global textvar
        wm title .s "Next $textvar words: [.s cget -word]"
        puts "Next $textvar words: [.s cget -word]"
    }
    proc Find {} {
        global textvar
        wm title .s "Find $textvar words: [.s cget -word]"
        puts "Find $textvar words: [.s cget -word]"
    }
    
    set textvar test
    snitfinddialog .s -case 1 -findnextcmd Next -findcmd Find -textvariable textvar
    wm title .s "Search "
   
    .s find configure -bg red
    set btn [.s find]
    $btn configure -bg blue
    bind [.s find] <Enter> {wm title .s "Yeah Here Find, I am entered!" ; puts "Yeah Here Find, I am entered!"}
    bind [.s next] <Enter> {wm title .s "Yeah Here Next, I am entered!" ; puts "Yeah Here Next, I am entered!"} 
    catch {tkwait visibility .s}
    catch {grab .s}
 }

 pack [button .b -text "Launch Find Dialog" -command Test_Find]